前回は、ThunderbirdのSieveアドオンを導入し、正常に動作しているかどうかのテストを行いました。
今回は、Sieve言語を用いてemailフィルターの記述をしていくことにします。
前回の補足
「ツール」>「Sieve Message Filters」の画面で、「Connect」を押してもサーバーにつながらない、といった声がありましたので補足しておきます。
ThunderbirdのSieveアドオンでは、TLS接続が必須になっています。プロキシの設定が施されているとうまくいかない場合がありますので、このあたりの設定を見直してくださいね。
よく分からない場合は、サーバー管理者へ問い合わせてみましょう。
PDFをKindleへ流し込む
転送の設定
それでは本題に戻りましょう。まずは以前、メールクライアント設定で添付されてきたemailをそのままKindleへ送り込む設定を施しましたが、まずは同じ動作をSieveでもやってみます。
#test1-1
require ["copy"];
if header :contains "From" "example.co.jp"
{
redirect "example_to_kindle@kindle.com";
}
こんな感じで、以前と同じように転送されましたね。(Send to Kindle側でメールアドレスの追加を忘れないようにして下さい。)
・・・が、この設定だと何らかの原因で上手く送信出来ない場合、肝心のメール自体が簡単にロストしてしまいます。
転送した後のメールは要らないよ!と言っても、さすがに何らかのタイミングでロストするような事があると目も当てられませんので、念のため保存しておきます。
#test1-2
require ["copy", "fileinto"];
if header :contains "From" "example.co.jp"
{
redirect :copy "example_to_kindle@kindle.com";
fileinto "Trash";
}
こんな感じになりました。
ここではTrashフォルダ(ゴミ箱)に直接保存してます。
転送したメールは既読に
Trashフォルダ(ゴミ箱)に保存しましたが、上手く転送が行われている時はもう読む必要も無いので、自動で「既読」になって欲しいですよね。というわけで、既読の設定を追加します。
#test1-3
require ["copy", "fileinto", "imap4flags"];
if header :contains "From" "example.co.jp"
{
redirect :copy "example_to_kindle@kindle.com";
setflag "\\Seen";
fileinto "Trash";
}
Trashフォルダ(ゴミ箱)に到着したメールが既読状態になっている事を確認して下さい。
Subject: を変える
ここまでは、メールクライアントのフィルター設定でも出来ることのおさらいでした。
これからはお待ちかね、メールクライアントではできない事をやってみます。
今回のテーマである、Subject: を変えてみましょう。
サーバーが対応しているか確認
念のため、サーバー側が対応しているかどうか、Sieveアドオンの「Show Server Capabilities」を確認してみます。
editheaderが存在すればOKです。
Sieveが使えても、editheaderに対応していない場合もあります*1ので、その時はサーバー管理者にお願いしてみましょう。
Subject: を変更しつつ転送
今回は、Kindleへ送る際にPDF形式をKindle形式へ変換して欲しいので、Subject: を 「convert」に強制的に変えてみます。
#test1-4
require ["copy", "fileinto", "imap4flags", "editheader"];
if header :contains "From" "example.co.jp"
{
deleteheader "Subject";
addheader :last "Subject" "convert";
redirect :copy "example_to_kindle@kindle.com";
setflag "\\Seen";
fileinto "Trash";
}
これで、Kindle形式でパーソナルドキュメントとして登録されましたね!
今回の目的は達成です。お疲れさまでした。
まとめ
今回は、Kindle形式でPDFドキュメントを流し込むことに成功しました。
次回はもう一つの課題であったEvernoteへの保存です。お楽しみに。
前回の記事はこちらです。
キングストンKingstonノートPC用メモリ DDR4-2400 (PC4-19200) 8GB CL15 1.2V Non-ECC SODIMM 260pin KVR24S17S8/8 永久保証
- 発売日: 2016/11/18
- メディア: Personal Computers
*1:Pigeonhole/Sieve/Extensions/Editheader - Dovecot Wiki 参照(The editheader extension is not available by default and needs to be enabled explicitly by adding it to the sieve_extensions setting. )